**3.56. Текущие дела**

Подсистема «Текущие дела» позволяет выводить список дел пользователя на рабочем столе (новые письма, задачи, заявки, несогласованные заказы и т. п.). Список дел определяется разработчиком конфигурации при внедрении подсистемы и может включать в себя важные и обычные дела, однострочные и многострочные, с количественными показателями и без. Список дел сгруппирован по разделам командного интерфейса, предусмотрена возможность настраивать видимость и порядок отображения, автоматическое обновление через заданный интервал.

**Настройка**

Разместить основную форму обработки ТекущиеДела в правой колонке рабочей области начальной страницы.

Принять решение по поводу состава дел, выводимых на рабочем столе. Например, это могут быть уведомления о новых письмах, задачах, заявках, несогласованных заказах и других делах, с которыми сталкиваются пользователи по своим должностным обязанностям. С каждым делом необходимо связать форму списка или рабочего места, которое должно открываться по нажатию на гиперссылку дела.

Рекомендуется группировать дела по разделам командного интерфейса, в которых размещены команды открытия рабочих мест по разбору этих дел. Например, если работа с письмами и задачами предусмотрена в разделе Органайзер, то соответствующие им дела также следует размещать в этом разделе панели Текущие дела.

При этом с помощью процедуры ПриОпределенииПорядкаРазделовКомандногоИнтерфейса общего модуля ТекущиеДелаПереопределяемый можно указать порядок следования разделов панели, который в точности соответствует порядку в интерфейсе программы.

**Добавление нового дела**

Для добавления нового дела на панель Текущие дела необходимо в процедуре ПриОпределенииОбработчиковТекущихДел общего модуля ТекущиеДелаПереопределяемый объявить общий модуль или модуль менеджера объекта, который будет предоставлять сведения об этом деле. Например:

[Копировать в буфер обмена](javascript:)

Процедура ПриОпределенииОбработчиковТекущихДел(Обработчики) Экспорт

Обработчики.Добавить(Документы.\_ДемоЗаказПокупателя);

КонецПроцедуры

После этого необходимо в указанном модуле определить экспортную процедуру ПриЗаполненииСпискаТекущихДел по шаблону:

[Копировать в буфер обмена](javascript:)

// Заполняет список текущих дел пользователя.

//

// Параметры:

//  ТекущиеДела - ТаблицаЗначений - таблица с колонками:

//   \* Идентификатор           - Строка - внутренний идентификатор дела, используемый механизмом "Текущие дела".

//   \* ЕстьДела                - Булево - если Истина, дело выводится в списке текущих дел пользователя.

//   \* Важное                  - Булево - если Истина, дело будет выделено красным цветом.

//   \* Представление           - Строка - представление дела, выводимое пользователю.

//   \* Количество              - Число  - количественный показатель дела, выводится в строке заголовка дела.

//   \* Форма                   - Строка - полный путь к форме, которую необходимо открыть при нажатии на гиперссылку

//                                        дела на панели "Текущие дела".

//   \* ПараметрыФормы          - Структура - параметры, с которыми нужно открывать форму показателя.

//   \* Владелец                - Строка, объект метаданных - строковый идентификатор дела, которое будет владельцем для текущего

//                               или объект метаданных подсистема.

//   \* Подсказка               - Строка - текст подсказки.

//

Процедура ПриЗаполненииСпискаТекущихДел(ТекущиеДела) Экспорт

КонецПроцедуры

И вписать в нее код по добавлению дел в таблицу ТекущиеДела.

Важно!

При добавлении дела необходимо проверять право Редактирование текущего пользователя на объект метаданных, предоставляющий это дело, а также значения функциональных опций (если они предусмотрены).

Пример заполнения дела по документам \_ДемоЗаказПокупателя:

[Копировать в буфер обмена](javascript:)

Процедура ПриЗаполненииСпискаТекущихДел(ТекущиеДела) Экспорт

Если Не ПравоДоступа("Редактирование", Метаданные.Документы.\_ДемоЗаказПокупателя) Тогда

Возврат;

КонецЕсли;

КоличествоЗаказовПокупателя = КоличествоЗаказовПокупателя();

СписокОтбора = Новый СписокЗначений;

СписокОтбора.Добавить(Перечисления.\_ДемоСтатусыЗаказовПокупателей.НеСогласован);

СписокОтбора.Добавить(Перечисления.\_ДемоСтатусыЗаказовПокупателей.Согласован);

ИдентификаторЗаказыПокупателя = "ЗаказыПокупателя";

Дело = ТекущиеДела.Добавить();

Дело.Идентификатор  = ИдентификаторЗаказыПокупателя;

Дело.ЕстьДела       = КоличествоЗаказовПокупателя.Всего > 0;

Дело.Представление  = НСтр("ru = 'Заказы покупателя'");

Дело.Количество     = КоличествоЗаказовПокупателя.Всего;

Дело.Форма          = "Документ.\_ДемоЗаказПокупателя.Форма.ФормаСписка";

Дело.ПараметрыФормы = Новый Структура("Отбор", Новый Структура("СтатусЗаказа", СписокОтбора));

Дело.Владелец       = Метаданные.Подсистемы.\_ДемоОрганайзер;

Дело = ТекущиеДела.Добавить();

Дело.Идентификатор  = "ЗаказыПокупателяНеСогласовано";

Дело.ЕстьДела       = КоличествоЗаказовПокупателя.НеСогласовано > 0;

Дело.Важное         = Истина;

Дело.Представление  = НСтр("ru = 'Не согласовано'");

Дело.Количество     = КоличествоЗаказовПокупателя.НеСогласовано;

Дело.Владелец       = ИдентификаторЗаказыПокупателя;

Дело = ТекущиеДела.Добавить();

Дело.Идентификатор  = "ЗаказыПокупателяСогласовано";

Дело.ЕстьДела       = КоличествоЗаказовПокупателя.Согласовано > 0;

Дело.Представление  = НСтр("ru = 'Согласовано'");

Дело.Количество     = КоличествоЗаказовПокупателя.Согласовано;

Дело.Владелец       = ИдентификаторЗаказыПокупателя;

КонецПроцедуры

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к функциям подсистемы «Текущие дела» нужно использовать следующую роль:

Таблица 3.115.

| № | Роли и их назначение |
| --- | --- |
| 1. | ИспользованиеТекущихДел  Предоставляет доступ для работы со списком текущих дел |

**Использование при разработке конфигурации**

**Настройка обмена данными**

Для настройки обмена данными никаких действий не требуется, так как подсистема не предоставляет собственных данных.